#
# Copyright (c) 2004-2007 - Consultas, PKG.fr
#
# This file is part of A2P.
#
# A2P is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# A2P is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with A2P; if not, write to the Free Software
# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
#
# $Id: IMM.pm 3 2007-10-18 16:20:19Z root $
#
# Class to export Invoke Medium Map (COPYGROUP) members
#
# cf ref #2, p. 178-179
#

package AFPDS::MODCA::IMM ;

use strict ;
use A2P::Globals ;
use A2P::Syslog ;
use AFPDS::MODCA::Common ;

BEGIN {
    our $VERSION = sprintf "%s", q$Rev: 1007 $ =~ /([0-9.]+)\s+/ ;
}
our $VERSION ;
our @ISA = ("AFPDS::MODCA");
our $IDENTS ;

sub _ID { 0xD3ABCC }

sub new {
    my $class = shift ;
    &Debug("new " . __PACKAGE__ . " v$VERSION object");

    my $self = {
        FLUX     => 0,        # Associated flux
        IDENT    => _ID,      # MO:DCA identity
        FLAG     => 0,        # MO:DCA flags
        RESERVED => 0,        # MO:DCA reserved
        LONG     => 0,        # MO:DCA buffer length
        BUFFER   => ''        # MO:DCA content buffer
    };

    return bless $self , $class ;
}

sub validate {
    my $self = shift ;

    &UPSTAT('GETCOPYGROUP');
    &Debug("Found IMM as COPYGROUP");

    # Check buffer size
    if ( $self->{LONG} != 8 ) {
        &Debug("Found IMM Field value with bad length (" . $self->{LONG} .
            "), keeping only the first 8 chars");
        $self->{BUFFER} = substr( $self->{BUFFER} , 0 , 8 );
    }

    # Check FLUX is a Flux object
    return ( 251, "IMM needs to be used with Flux object" )
        unless ( ref($self->{FLUX}) =~ /^AFPDS::Flux$/ );

    return () ;
}

sub create {
    my $self = shift ;
    my $flux = $self->{FLUX} ;

    # Convert buffer
    my $copygroup = $self->convert ;

    # Prepare TeX/LaTeX copygroup code
    my $CopyGroup = "";

    # Close the previous defined PageFormat before setting CopyGroup
    $CopyGroup = "}%\n" if ($flux->has_pageformat);

    # Update TeX/LaTeX copygroup code
    $CopyGroup .= "%\n\\ResetOffset%\n\\CopyGroup" ;

    # Parse found copygroup name to reset number as lowcase chars
    for ( split( // , $copygroup ) ) {
        if ( /\d/ ) {
            $CopyGroup .= chr( 97 + $_ ) ;
        } else {
            $CopyGroup .= uc( $_ ) ;
        }
    }

    $flux->updateFlux( {
        COPYGROUP => $CopyGroup . "% Load '$copygroup' COPYGROUP",

        # Keep information on this use for statistics
        COPYGROUPs => { $copygroup => 1 }
        } );

    &UPSTAT('USECOPYGROUP_' . $copygroup);

    return () ;
}

&Debug("Module " . __PACKAGE__ . " v$VERSION loaded");

( $IDENTS->{&_ID} ) = __PACKAGE__ =~ /(\w+)$/ ;
